【VS Code】第7回「VS CodeでRPGプログラムの単体テストを実行してみよう」

3.事前準備

前提条件については、今後変更の可能性があるため、公式ドキュメント（IBM i Testing Overview）を参照するようにしてください。

必要な機能拡張

VS Codeに以下の拡張機能がインストールされていることを確認してください。（いずれも必須）

• IBM i Testing（IBM.vscode-ibmi-testing）
• Code for IBM i（バージョン 2.16.0 以上）
• RPGLE（バージョン 0.31.0 以上）

IBM i 側の前提条件

• IBM i 7.5以上を推奨します。
• IBM i 7.3 / 7.4の場合は、下表のPTFがインストールされていれば利用可能です。

RPGUnitのセットアップ

RPGUnitは、IBM i Testingの機能から直接インストールできます。
1. VS CodeでIBM i に接続します。
2. ステータスバーの接続名にカーソルを合わせ、Settingsを選択します。
3. Componentsタブに移動し、Install componentを押下します。
   
4. 一覧から RPGUnitを選択し、OKを押下します。
   
5. Proceedを押下します。
   
6. IBM i Testingの出力チャンネルで、インストールの進捗を確認できます。完了通知が表示されれば、セットアップは完了です。
   
   
   ^{※ 上記画像をクリックすると、新規タブに拡大表示されます。}

CODECOVのセットアップ

コードカバレッジを利用するには、IBM i にCODECOVコマンドをPTFでインストールする必要があります（5770WDS）。

• IBM i 7.3：PTF SI80728
• IBM i 7.4：PTF SI80737 および SI81204
• IBM i 7.5：PTF SI81216 および SI81217
• IBM i 7.6：PTF 適用不要

4.サンプルソースを準備する

• 今回は IBM が公開しているサンプルリポジトリ ibmi-company-system を使用します。
• このリポジトリには、テストの練習に適したRPGソースと既存のテストスイートが含まれています。

ダウンロード方法

Gitを利用する場合

• VS Codeでコマンドパレット（Ctrl+Shift+P）を開き git clone と入力します。
• 以下のURLを貼り付けてクローンします。
  https://github.com/IBM/ibmi-company_system.git

Gitを利用しない場合

• リポジトリのページにアクセスし、Code → Download ZIP でダウンロードします。
• 任意のフォルダーに解凍し、VS Codeで開きます。

IBM i 環境へのビルド

• テストを実際に実行するには、IBM i 側にサンプルプログラムやDBのオブジェクトが必要です。
• 以下は、参考手順です。VS Codeのターミナルから SSH で IBM i に接続し、実行してください。

  # パスを通す（未設定の場合）
  export PATH=/QOpenSys/pkgs/bin:$PATH

  # TOBi と IBMi Repos をインストール（未インストールの場合）
  yum install ibmi-repos tobi

  # オブジェクト配置先ライブラリーを作成
  cl "CRTLIB LIB(CMPSYS) TEXT('Company System')"

  # サンプルリポジトリをクローン
  git clone https://github.com/IBM/ibmi-company\_system
  cd ibmi-company\_system

  # 環境変数を設定してビルド
  export CURLIB=CMPSYS
  makei build

VS Codeから、Code for IBM i を使って IBM i に接続

未接続の場合は、RPGUnit を導入した IBM i に接続します。

サンプルソースの全体像

• ダウンロードしたサンプルには、テスト対象プログラムとテストスイートがセットで含まれています。
• 今回は、以下画像の2ファイルを使ってテストの流れを体験します。
  
  ※ 上記画像をクリックすると、新規タブに拡大表示されます。
• qrpglesrc/empdet.sqlrpgle（テスト対象プログラム）：ctl-opt nomain で宣言し、getEmployeeDetail（社員詳細取得）と getDeptDetail（部署詳細取得）の2つのプロシージャを持ちます。
• qtestsrc/empdet.test.sqlrpgle（テストスイート）：setUpSuite でモックテーブルを準備し、正常系・異常系あわせて計4つのテストケースが定義されています。

5.命名規則を理解する

IBM i Testingでテストを検出するには、ファイル名やメンバー名が、一定の命名規則を満たす必要があります。

テストケースの命名規則

RPGUnit では、test で始まる名前のエクスポートプロシージャがテストケースとして認識されます。
逆に言うと、テストケースとして意図していないプロシージャを test で始まる名前でエクスポートしてはいけません。

  // テストケースとして認識される
  dcl-proc test\_getEmployeeDetail export;
  dcl-proc testIsPalindrome export;

  // テストケースとして意図しない場合はNG
  dcl-proc testHelper export;   // test で始まるので検出されてしまう

テストスイートの命名規則

テストスイートとは、1つ以上のテストケースを含むファイルまたはソースメンバーです。テストスイートはサービスプログラムにコンパイルされ、テストケースが実行されます。

RPGUnit自体はテストスイートの命名規則を強制しません。命名規則を適用するのは、IBM i Testing 拡張機能です。
IBM i Testingは、PC上のローカルファイルとIBM i 上のソースメンバー（QSYS）のどちらでも、テストを検出・実行できます。ただし、それぞれ、命名規則が異なります。

  // テストケースとして認識される
  dcl-proc test\_getEmployeeDetail export;
  dcl-proc testIsPalindrome export;

  // テストケースとして意図しない場合はNG
  dcl-proc testHelper export;   // test で始まるので検出されてしまう

ローカルファイルの例

  employee.test.rpgle
  department.test.sqlrpgle

ソースメンバーの例（QTESTSRCソースファイル内）

  EMPLOYEET.RPGLE
  T\_STRING.RPGLE

6.テストスタブを自動生成する

テストコードを0から書くのは、やや大変ですよね。IBM i Testing には、テストスタブ（テストコードの雛形）を自動生成する機能があります。

スタブ生成の手順

1. サンプルソースの /qrpglesrc/empdet.sqlrpgle を、VS Codeで開きます。
2. ファイル内の任意の場所にカーソルを置きます。
3. コードアクションボタン（💡）を押下します。
   
   
   ・Generate test case for getEmployeeDetail：このプロシージャのテストケースのみ生成
   ・Generate test suite for empdet`：ファイル内の全プロシージャのテストスイートを一括生成
   
4. 今回は、Generate test suite for empdet を選択します。
5. リファクター・プレビューで確認し、すべてにチェックをいれ`適用`を押下します。
   
   ※ 上記画像をクリックすると、新規タブに拡大表示されます。
6. /qtestsrc/empdet.test.sqlrpgle が作成されます。

生成されたスタブの構造

Generate test suite for empdet を選択すると、ファイル内の全エクスポートプロシージャ分のテストケースが一括生成されます。

今回は getEmployeeDetail と getDeptDetail の2プロシージャ分が生成されます。なお、コメント行は記事用に追記しているものであり、自動生成はされません。

**free

ctl-opt nomain ccsidcvt(\*excp) ccsid(\*char : \*jobrun);

/include qinclude,TESTCASE
/include 'qrpgleref/empdet.rpgleinc'

dcl-proc test\_getEmployeeDetail export;
  dcl-pi \*n extproc(\*dclcase) end-pi;

  // ① DECLARATIONS（宣言）: テストに必要な変数とデータ構造
  dcl-s empno char(6);
  dcl-ds actual likeDs(employee\_detail\_t) inz;
  dcl-ds expected likeDs(employee\_detail\_t) inz;

  // ② INPUTS（入力）: テスト対象プロシージャに渡す入力値 ← ここを修正
  empno = '';

  // ③ ACTUAL RESULTS（実際の結果）: プロシージャを実行して結果を取得
  actual = getEmployeeDetail(empno);

  // ④ EXPECTED RESULTS（期待される結果）← ここを修正
  expected.found = \*off;
  expected.name = '';
  expected.netincome = 0.0;

  // ⑤ ASSERTIONS（アサーション）: 実際の結果と期待値を比較
  nEqual(expected.found : actual.found : 'found');
  assert(expected.name = actual.name : 'name');
  assert(expected.netincome = actual.netincome : 'netincome');
end-proc;

dcl-proc test\_getDeptDetail export;
  dcl-pi \*n extproc(\*dclcase) end-pi;

  // ① DECLARATIONS（宣言）: テストに必要な変数とデータ構造
  dcl-s deptno char(3);
  dcl-ds actual likeDs(department\_detail\_t) inz;
  dcl-ds expected likeDs(department\_detail\_t) inz;

  // ② INPUTS（入力）: テスト対象プロシージャに渡す入力値 ← ここを修正
  deptno = '';

  // ③ ACTUAL RESULTS（実際の結果）: プロシージャを実行して結果を取得
  actual = getDeptDetail(deptno);

  // ④ EXPECTED RESULTS（期待される結果）← ここを修正
  expected.found = \*off;
  expected.deptname = '';
  expected.location = '';
  expected.totalsalaries = 0.0;

  // ⑤ ASSERTIONS（アサーション）: 実際の結果と期待値を比較
  nEqual(expected.found : actual.found : 'found');
  assert(expected.deptname = actual.deptname : 'deptname');
  assert(expected.location = actual.location : 'location');
  assert(expected.totalsalaries = actual.totalsalaries : 'totalsalaries');
end-proc;

各テストケースは以下の5つのセクションで構成されています。開発者が修正すべき箇所は ②INPUTS と ④EXPECTED RESULTS の2か所だけです。残りのセクションは通常そのままで使えます。

期待値を設定する

今回は2つのテストケースそれぞれに、正常系の期待値を設定します。

test_getEmployeeDetail の期待値設定

• まず、以下のSQLで CMPSYS/EMPLOYEE にテストデータを追加します。
  

    INSERT INTO CMPSYS.EMPLOYEE
      (EMPNO, FIRSTNME, MIDINIT, LASTNAME, WORKDEPT, PHONENO,
       HIREDATE, JOB, EDLEVEL, SEX, BIRTHDATE, SALARY, BONUS, COMM)
    VALUES
      ('12345', 'ZAKURO', 'J', 'KOINUMA', '55', '08',
       '2023-04-18', 'POWER', 0, 'F', '2023-04-17', 10, 20, 30)
  

• 次に、スタブの ② と ④ を以下のように修正します。
  

    // ② INPUTS（入力）を修正
    empno = '12345';
  
    // ④ EXPECTED RESULTS（期待される結果）を修正
    expected.found = \*on;
    expected.name = 'ZAKURO J KOINUMA';
    expected.netincome = 60.00;
  

test_getDeptDetail の期待値設定

• まず、以下の SQL で CMPSYS/DEPARTMENT にテストデータを追加します。EMPLOYEE.WORKDEPTが55なので、部署番号も55に合わせます。
  

    INSERT INTO CMPSYS.DEPARTMENT (DEPTNO, DEPTNAME, MGRNO, ADMRDEPT, LOCATION)
    VALUES ('55', 'SYSTEM DEVELOPMENT', '12345', '55', 'TOKYO')
  

• スタブの ② と ④ を以下のように修正します。
  

    // ② INPUTS（入力）を修正
    deptno = '55';
  
    // ④ EXPECTED RESULTS（期待される結果）を修正
    expected.found = \*on;
    expected.deptname = 'SYSTEM DEVELOPMENT';
    expected.location = 'TOKYO';
    expected.totalsalaries = 60.00;
  

• Ctrl+S で保存します。

7.テスト実行前の設定

testing.jsonとは

IBM i Testing は、テストのコンパイル・実行方法を testing.json という設定ファイルで管理します。
このファイルでは RUCRTRPG（RPGテストのコンパイル）、RUCRTCBL（COBOLテストのコンパイル）、CODECOV（カバレッジ計測）のパラメーターをJSON形式で指定できます。

testing.jsonの配置場所

ディレクトリーレベルの設定が優先され、設定されていない項目はプロジェクト全体の設定から継承されます。

testing.jsonの設定例

今回は /qtestsrc/testing.json を使用します。以下の内容を設定します。

{
    "rpgunit": {
        "rucrtrpg": {
            "tgtCcsid": "\*JOB",
            "dbgView": "\*SOURCE",
            "rpgPpOpt": "\*LVL2",
            "bndDir": \["CMPSYS/APP"],
            "cOption": \[
                "\*EVENTF"
            ]
        }
    },
    "codecov": {
        "module": \[
            "CMPSYS/EMPDET"
        ]
    }
}

IBM i Project Explorer のセットアップ

IBM i Testingでローカルファイルをコンパイル・実行するには、IBM i Project ExplorerでプロジェクトとIFSを紐づける必要があります。この詳細な手順は、第6回「VS CodeでGitを使ってIBM i のソースを管理してみよう」を参照ください。本記事では、サンプルリポジトリに必要な設定をさらっと進めます。

IFSデプロイ先の設定

1. エクスプローラーの PROJECT EXPLORER エリアを開きます。
2. Source の →（Please configure deploy location）を押下します。
3. IFSのデプロイ先パスを確認し、Enterを押下します（デフォルト: /home/ユーザー名/builds/ibmi-company_system）。

ライブラリーリストの設定

• PROJECT EXPLORER エリアの Library List からライブラリーを追加します。
  ※ RPGUNIT、QDEVTOOLS を追加します。
• Library List の Set Current Library でカレントライブラリーに CMPSYS を設定します。

設定後、iproj.json は、以下のようになります。

  {
    "description": "Company System project",
    "includePath": \["qrpgleref"],
    "curlib": "\&CURLIB",
    "objlib": "\&CURLIB",
    "preUsrlibl": \[
      "\&CURLIB",
      "RPGUNIT",
      "QDEVTOOLS"
    ],
    "buildCommand": "/QOpenSys/pkgs/bin/gmake BIN\_LIB=\&CURLIB"
  }

8.テストを実行する

テストの検出と実行

1. VS Codeで、IBM i に接続します。
2. IBM i Testing 拡張機能が、ワークスペース内の .test.rpgle ファイルを自動的に検出します。
3. アクティビティバーのテストエクスプローラー（ビーカーアイコン）を押下すると、検出されたテストが一覧表示されます。
   
4. プロシージャごとにテストもできますが、今回は empdet.test.sqlrpgle を選択し、テストスイートのテストを実行します。テスト実行ボタン（▶）を押下します。
5. デプロイ方法の確認ダイアログが表示されたら Compare を選択します。
   ※ ローカルの最新テストソースが IFS へアップロードされた後、テストが実行されます。

テスト結果の確認

テスト実行後、テストエクスプローラーに結果が表示されます。

上記画像をクリックすると、新規タブに拡大表示されます。

PASS が表示されれば成功です。正常系の動きが期待通りであることが確認できました。

FAIL が表示された場合は、失敗箇所がVS Codeのエディター上にインラインで表示されます。

終わりに

• 今回は IBM i Testing を使って、VS CodeからRPGプログラムの単体テストを実行する基本的な流れを体験しました。
• スタブ自動生成 → 期待値を設定 → テスト実行 → 結果確認 というサイクルを繰り返すことで、品質を保ちながら開発を進めることができます。
• 今回は、コードカバレッジについては触れませんでした。ぜひ、テスト実行時のコードカバレッジのエディター上の可視化もお試しください。（テスト実行のボタンの横にあります）
• また、Git と組み合わせることで、featureブランチで開発 → テストをパスしたらマージという、より実践的な開発フローも実現できます。
• IBM i の開発も、テストの自動化を当たり前にすることでもっと楽しく、もっと安心して進めていきましょう！

筆者